Windows家庭版开启组策略

Windows的组策略对于优化和维护Windows系统来说十分重要，但是Windows的家庭版里没有组策略（限制了组策略），打开直接报错，提示“Windows找不到文件‘gpedit.msc’。请确定文件名是否正确后，再试一次。”

以下讲讲如何在Windows家庭版中开启组策略。本文以Windows11家庭版为例。

操作方法

1、打开文本文档，输入以下代码，并保存为Enable-gpedit.cmd（注意：后缀名为cmd），文章最后也有写好的cmd文件供下载。

@echo off
title Windows家庭版解锁组策略  By StarYu https://www.77bx.com
openfiles >nul 2>nul ||(
echo CreateObject^("Shell.Application"^).ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs" >nul 2>&1
goto:eof
)
del /f /q "%temp%\getadmin.vbs" >nul 2>nul
cls
echo ============================================================================
echo # Windows家庭版解锁组策略
echo.
echo # By StarYu https://www.77bx.com
echo.
echo # 支持:
echo - Microsoft Windows 10 家庭版
echo - Microsoft Windows 11 家庭版
echo ============================================================================
echo # 按任意键开始解锁
echo.
pause >nul
echo.
for /f %%i in ('dir /b %SystemRoot%\servicing\Packages\Microsoft-Windows-GroupPolicy-ClientExtensions-Package~3*.mum') do dism /online /norestart /add-package:"%SystemRoot%\servicing\Packages\%%i"
for /f %%i in ('dir /b %SystemRoot%\servicing\Packages\Microsoft-Windows-GroupPolicy-ClientTools-Package~3*.mum') do dism /online /norestart /add-package:"%SystemRoot%\servicing\Packages\%%i"
cls
echo ============================================================================
echo #  解锁完成，按任意键结束
echo ============================================================================
pause >nul

2、运行Enable-gpedit.cmd，会弹出用户控制权限，点击 是 （这边是申请管理员权限运行），然后按任意键开始，大概等待1分钟，完成后按任意键关闭窗口

3、开始 -> 运行（Win + R 快捷键），输入 gpedit.msc 回车，可以看到可以打开组策略了。